Bz Buzz

Ispirati al comportamento degli insetti, che non elaborano una mappa dettagliata dell'ambiente in cui si muovono ma si limitano a ricordare punti di riferimento importanti come le fonti di cibo o il nido, i micro droni si muovevano esplorando autonomamente l'ambiente sconosciuto; l'idea principale alla base del nuovo metodo di navigazione era di ridurre le aspettative all'estremo: si richiedeva ai piccoli robot che fossero capaci solamente di tornare alla stazione base. Lo sciame di robot dapprima si sparpagliava nell'ambiente lasciando a ciascun componente la scelta di una direzione preferita, differente da quella degli altri membri dello sciame. Dopo l'esplorazione gli insetti robot tornavano verso il wireless beacon situato alla stazione base; ma qualcosa andò storto e lo sciame dei micro droni impazzì;

(
fork {   
    Ndef(\nbz).play;
    loop {
        var seed = thisThread.randSeed = 171300000.rand.debug('seed');
        Ndef(\nbz, {
            var freq = [713, 1337];
            Splay.ar(
                {
                    var bands = 2.rrand(10);
                    var signal = { [BPF,RLPF,RHPF].choose.ar(
                        HenonN.ar(freq[0].rrand(freq[1]), LFPulse.kr(0.1.exprand(10))),
                        Array.rand(bands, freq[0], freq[1]),
                        Array.rand(bands, 0.2, 1.8)
                    ).mean } ! 2;
                    Rotate2.ar(signal[0], signal[1], SinOsc.kr(0.1.exprand(10)));
                } ! 3.rrand(7).debug('source'), // creazione dell'array da passare a Splay
                                0.5.rrand(1) // spread dell'Splay
            );
        }).fadeTime_(1.rrand(1.3)); // fadeTime randomico
        10.0.rrand(13).debug('wait(bts)').wait;
    }
}
)